highLight Search results

[tcadieux]

i'm using the below code to highlight some keywords on a page, it works awesome, only 1 thing, it only highlights a part of a word..

strSearch="cat"

results = catacomb...

is there a way to make the script highlight the whole word...

example catacomb

Function Highlight(strText, strFind, strBefore, strAfter)
    Dim nPos
    Dim nLen
    Dim nLenAll
    
    nLen = Len(strFind)
    nLenAll = nLen + Len(strBefore) + Len(strAfter) + 1

    Highlight = strText

    If nLen > 0 And Len(Highlight) > 0 Then
        nPos = InStr(1, Highlight, strFind, 1)
        Do While nPos > 0
            Highlight = Left(Highlight, nPos - 1) & _
                strBefore & Mid(Highlight, nPos, nLen) & strAfter & _
                Mid(Highlight, nPos + nLen)

            nPos = InStr(nPos + nLenAll, Highlight, strFind, 1)
        Loop
    End If
End Function 

[Spudhead]

Tested only briefly, and my regExp skills are... minimal... but try this:

function highlightWords(sSearchString, sCopyText)
	dim oRegEx, oMatches, oMatch
	set oRegEx = New RegExp
	oRegEx.Global = True 
	oRegEx.IgnoreCase = False
	oRegEx.Pattern = "\b\S*("&sSearchString&")\S*\b"
	set oMatches = oRegEx.Execute(sCopyText)
	For Each oMatch in oMatches
		sCopyText = replace(sCopyText, oMatch.value, "<span style=""color:yellow;"">" & oMatch.value & "</span>")
	Next
	highlightWords = sCopyText
end function