Tweet
I went there and followed the directions and copied their form for testing, and uploaded it here:
I cheated the tags, but here is the ASP code that I am trying to use.
<%@ Language=VBScript %>
<% Option Explicit %>
<%
'The header/footer for the email.
Const strHeader = "Here are the results of the form:"
Const strFooter = "Form mailer created by 4GuysFromRolla.com, 1999"
'Who does this go to?
Const strTo = "[email protected]"
'This information is optional
Dim strFrom, strSubject, strRedirectURL, strFromPath
strFrom = Request.Form("txtSendToEmailAddress")
if Len(strFrom) = 0 then strFrom = strTo
strSubject = Request.Form("txtEmailSubject")
if Len(strSubject) = 0 then strSubject = "FORM EMAILER: 4GuysFromRolla.com, 1999"
strRedirectURL = Request.Form("urlSendTo")
if Len(strRedirectURL) = 0 then strRedirectURL = "/"
strFromPath = Request.Form("urlFromPath")
if Len(strFromPath) = 0 then strFromPath = "UNKNOWN"
Dim strBody
strBody = strHeader & vbCrLf & vbCrLf
strBody = strBody & "FORM: " & strFromPath & vbCrLf & _
"FORM submitted at " & Now() & vbCrLf & vbCrLf
Dim myElement
For Each myElement in Request.Form
Select Case Left(myElement,3)
Case "txt","sel","rad":
strBody = strBody & Replace(Mid(myElement,4,len(myElement)),"."," ") & _
": "
if Len(Request.Form(myElement)) = 0 then
strBody = strBody & "UNANSWERED"
else
strBody = strBody & Request.Form(myElement)
end if
strBody = strBody & vbCrLf
Case "chk":
strBody = strBody & Replace(Mid(myElement,4,len(myElement)),"."," ") & _
": " & Request.Form(myElement) & vbCrLf
End Select
Next
strBody = strBody & vbCrLf & strFooter
'Time to send the email
Dim objCDO
Set objCDO = Server.CreateObject("CDONTS.NewMail")
objCDO.To = strTo
objCDO.From = strFrom
objCDO.Subject = strSubject
objCDO.Body = strBody
objCDO.Send
Set objCDO = Nothing
Response.Redirect strRedirectURL
%>
Comment